Dependencies

Table of Contents

  1. README.md
  2. src/dependencies.litcoffee
  3. src/index.litcoffee
  4. src/overseer.litcoffee
  5. src/prototypes/parser_proto.litcoffee
  6. src/prototypes/service_proto.litcoffee
  7. src/services.litcoffee
  8. src/workers.litcoffee
  9. CONTRIBUTING.md

Overview

Check dependency graph for cycles. Throw a CycleError if one is found, detailing the services involved.

Source-through

_ = require 'underscore'

class CycleError extends Error
    constructor: (dependency, walkedList) ->
        index = _.indexOf walkedList, dependency
        cycle = _.reject walkedList, (s) -> _.indexOf(walkedList, s) < index
        cycle.push dependency
        @message = "Cyclic Dependency found: '#{cycle.join '\' -> \''}'"
    name: 'Cyclic Dependency Error'

module.exports = (graph) ->
    services = _.keys graph
    visited = []

    visitNode = (service, walked) ->
        walked = [] unless _.isArray walked
        visited.push service
        walked.push service
        visitDependencies = (dependency) ->
            if _.contains walked, dependency
                throw new CycleError dependency, walked

            visitNode dependency, walked.slice 0

        _.each graph[service], visitDependencies

    _.each services, visitNode

    return true
h